折线图

项目
10/03/2024

适用于：✅Azure 数据资源管理器✅Azure Monitor✅Microsoft Sentinel

折线图视觉对象是最基本的图表类型。查询的第一列应是数值，并且用作 x 轴。其他数值列是 y 轴。折线图跟踪短期和长期的变化。存在较小的变化时，折线图比条形图更有用。

注意

此可视化效果只能在 render 运算符的上下文中使用。

语法

T | render linechart [with ( propertyName = propertyValue [, ...])]

详细了解语法约定。

参数

客户	类型	必需	说明
T	`string`	✔️	输入表名称。
propertyName, propertyValue	`string`		键值属性对的逗号分隔列表。请参阅支持的属性。

支持的属性

所有属性都是可选的。

PropertyName	PropertyValue
`accumulate`	是否将每个度量的值加到其所有前导度量中（`true` 或 `false`）。
`legend`	是否显示图例（`visible` 或 `hidden`）。
`series`	以逗号分隔的列列表，其中的每记录值组合定义了记录所属的系列。
`ymin`	要在 Y 轴上显示的最小值。
`ymax`	要在 Y 轴上显示的最大值。
`title`	可视化效果的标题（`string` 类型）。
`xaxis`	如何缩放 x 轴（`linear` 或 `log`）。
`xcolumn`	结果中的哪一列用于 x 轴。
`xtitle`	x 轴的标题（`string` 类型）。
`yaxis`	如何缩放 y 轴（`linear` 或 `log`）。
`ycolumns`	由逗号分隔的列列表，其中包含根据 x 列的值提供的值。
`ysplit`	如何拆分多个可视化效果。有关详细信息，请参阅 `ysplit` property。
`ytitle`	y 轴的标题（`string` 类型）。

`ysplit` 属性

此可视化效果支持拆分为多个 y 轴值：

`ysplit`	描述
`none`	为所有系列数据显示单个 y 轴。（默认值）
`axes`	单个图表将显示多个 y 轴（每个系列一个）。
`panels`	为每个 `ycolumn` 值呈现一个图表（直至达到某个限制）。

示例

呈现折线图

StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart

标记折线图

StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart
    with (
    title="Property damage from storms in Virginia",
    xtitle="Start time of storm",
    ytitle="Property damage"
    )

y 轴上显示的限制值

StormEvents
| where State=="VIRGINIA"
| project StartTime, DamageProperty
| render linechart with (ymin=7000, ymax=300000)

查看多个 y 轴

StormEvents
| where State in ("TEXAS", "NEBRASKA", "KANSAS") and EventType == "Hail"
| summarize count() by State, bin(StartTime, 1d)
| render linechart with (ysplit=panels)

在 Web UI 中添加查询可视化效果。