replace_strings()

适用于：✅Azure 数据资源管理器✅Azure Monitor✅Microsoft Sentinel

将所有字符串匹配项替换为指定字符串。

若要替换单个字符串，请参阅 replace_string()。

语法

replace_strings(text, lookups, rewrites)

详细了解语法约定。

参数

返回

在使用 rewrites 计算结果替换 lookups 的所有匹配项后返回 text。 匹配项不会重叠。

示例

简单替换

print Message="A magic trick can turn a cat into a dog"
| extend Outcome = replace_strings(
        Message,
        dynamic(['cat', 'dog']), // Lookup strings
        dynamic(['dog', 'pigeon']) // Replacements
        )

替换为空字符串

替换为空字符串会删除匹配的字符串。

print Message="A magic trick can turn a cat into a dog"
| extend Outcome = replace_strings(
        Message,
        dynamic(['turn', ' into a dog']), // Lookup strings
        dynamic(['disappear', '']) // Replacements
        )

替换顺序

匹配元素的顺序非常重要：以先找到的匹配项优先。 请注意 Outcome1 和 Outcome2 之间的差别：This 与 Thwas。

 print Message="This is an example of using replace_strings()"
| extend Outcome1 = replace_strings(
        Message,
        dynamic(['This', 'is']), // Lookup strings
        dynamic(['This', 'was']) // Replacements
        ),
        Outcome2 = replace_strings(
        Message,
        dynamic(['is', 'This']), // Lookup strings
        dynamic(['was', 'This']) // Replacements
        )

非字符串替换

不是字符串的替换元素不会被替换，将保留原始字符串。 匹配项仍被视为有效，并且不会对匹配的字符串执行其他可能的替换。 在以下示例中，“This”不会替换为数字 12345，它将保留在输出中，不受与“is”可能匹配的影响。

 print Message="This is an example of using replace_strings()"
| extend Outcome = replace_strings(
        Message,
        dynamic(['This', 'is']), // Lookup strings
        dynamic([12345, 'was']) // Replacements
        )

相关内容

• 有关单个字符串的替换，请参阅 replace_string()。
• 有关基于正则表达式的替换，请参阅 replace_regex()。
• 若要替换一组字符，请参阅 translate()。