通过

ipv4_is_match()

  • 项目

适用于：✅Azure 数据资源管理器✅Azure Monitor✅Microsoft Sentinel

匹配两个 IPv4 字符串。 分析并比较两个 IPv4 字符串，同时考虑根据参数前缀和可选的 prefix 参数计算出的组合 IP 前缀掩码。

语法

ipv4_is_match(ip1,ip2[ ,prefix])

详细了解语法约定。

参数

客户 类型​​ 必需 说明
ip1, ip2 string ✔️ 一个表示 IPv4 地址的表达式。 可以使用 IP 前缀表示法对 IPv4 字符串进行掩码操作。
prefix int 从 0 到 32 的整数，表示所考虑的最有效位的数目。

IP 前缀表示法

IP 前缀表示法（也称 CIDR 表示法）是表示 IP 地址及其关联网络掩码的简明方式。 格式为 <base IP>/<prefix length>，其中，前缀长度是网络掩码中前导 1 位的数目。 前缀长度决定了属于该网络的 IP 地址范围。

对于 IPv4，前缀长度是介于 0 和 32 之间的数字。 因此，表示法 192.168.2.0/24 表示 IP 地址 192.168.2.0，且网络掩码为 255.255.255.0。 此网络掩码具有 24 个前导 1 位，或者说前缀长度为 24。

对于 IPv6，前缀长度是介于 0 和 128 之间的数字。 因此，表示法 fe80::85d:e82c:9446:7994/120 表示 IP 地址 fe80::85d:e82c:9446:7994 且网络掩码为 ffff:ffff:ffff:ffff:ffff:ffff:ffff:ff00。 此网络掩码具有 120 个前导 1 位，或者说前缀长度为 120。

返回

  • true：如果第一个 IPv4 字符串参数的长表示形式等于第二个 IPv4 字符串参数。
  • false：其他情况。
  • null：如果两个 IPv4 字符串之一转换不成功。

注意

针对非范围的 IPv4 地址进行匹配时，建议使用 equals 运算符 (==)，以提高性能。

示例

简单示例

print ipv4_is_match('192.168.1.1/24', '192.168.1.255')

输出

print_0
是

IPv4 比较相等 - IPv4 字符串中指定的 IP 前缀表示法

datatable(ip1_string:string, ip2_string:string)
[
 '192.168.1.0',    '192.168.1.0',       // Equal IPs
 '192.168.1.1/24', '192.168.1.255',     // 24 bit IP-prefix is used for comparison
 '192.168.1.1',    '192.168.1.255/24',  // 24 bit IP-prefix is used for comparison
 '192.168.1.1/30', '192.168.1.255/24',  // 24 bit IP-prefix is used for comparison
]
| extend result = ipv4_is_match(ip1_string, ip2_string)

输出

ip1_string ip2_string result
192.168.1.0 192.168.1.0 是
192.168.1.1/24 192.168.1.255 是
192.168.1.1 192.168.1.255/24 是
192.168.1.1/30 192.168.1.255/24 是

IPv4 比较相等 - IP 前缀表示法在 IPv4 字符串中指定，作为 ipv4_is_match() 函数的附加参数

datatable(ip1_string:string, ip2_string:string, prefix:long)
[
 '192.168.1.1',    '192.168.1.0',   31, // 31 bit IP-prefix is used for comparison
 '192.168.1.1/24', '192.168.1.255', 31, // 24 bit IP-prefix is used for comparison
 '192.168.1.1',    '192.168.1.255', 24, // 24 bit IP-prefix is used for comparison
]
| extend result = ipv4_is_match(ip1_string, ip2_string, prefix)

输出

ip1_string ip2_string 前缀 result
192.168.1.1 192.168.1.0 31 是
192.168.1.1/24 192.168.1.255 31 是
192.168.1.1 192.168.1.255 24 是

相关内容