通过

geo_union_polygons_array()

  • 项目

适用于：✅Azure 数据资源管理器✅Azure Monitor✅Microsoft Sentinel

计算地球上的多边形或多多边形的并集。

语法

geo_union_polygons_array(多边形)

详细了解语法约定。

参数

客户 类型​​ 必需 说明
polygons dynamic ✔️ 由采用 GeoJSON 格式的多边形或多多边形组成的数组。

返回

采用 GeoJSON 格式的 dynamic 数据类型的多边形或多多边形。 如果提供的任意多边形或多多边形无效，则查询会产生 null 结果。

注意

  • 以 WGS-84 坐标参考系统表示方法对地理空间坐标进行解释。
  • 用于在地球上进行测量的大地基准是一个球体。 多边形边缘是球体上的测地线。
  • 如果输入多边形边缘是直笛卡尔线，请考虑使用 geo_polygon_densify() 以将平面边缘转换为测地线。

多边形定义和约束

dynamic({"type": "Polygon","coordinates": [ LinearRingShell, LinearRingHole_1, ..., LinearRingHole_N ]})

dynamic({"type": "MultiPolygon","coordinates": [[ LinearRingShell, LinearRingHole_1, ..., LinearRingHole_N], ..., [LinearRingShell, LinearRingHole_1, ..., LinearRingHole_M]]})

  • LinearRingShell 是必需的，定义为 counterclockwise 有序坐标数组 [[lng_1,lat_1],...,[lng_i,lat_i],...,[lng_j,lat_j],...,[lng_1,lat_1]]。 只能有一个 shell。
  • LinearRingHole 是可选的，定义为 clockwise 有序坐标数组 [[lng_1,lat_1],...,[lng_i,lat_i],...,[lng_j,lat_j],...,[lng_1,lat_1]]。 可以有任意数量的内部环和孔。
  • LinearRing 顶点必须很独特，至少有三个坐标。 第一个坐标必须等于最后一个坐标。 至少需要四个条目。
  • 坐标 [经度, 纬度] 必须有效。 经度必须是 [-180, +180] 范围内的实数，纬度必须是 [-90, +90] 范围内的实数。
  • LinearRingShell 最多包含球体的一半。 LinearRing 将球体分成两个区域。 将选择这两个区域中较小的一个。
  • LinearRing 边缘长度必须小于 180 度。 将选择两个顶点之间的最短边缘。
  • LinearRing 不得交叉且不得共享边缘。 LinearRing 可以共享顶点。

示例

下面的示例对多边形行执行地理空间合并。

datatable(polygons:dynamic)
[
    dynamic({"type":"Polygon","coordinates":[[[-73.9495,40.7969],[-73.95807,40.80068],[-73.98201,40.76825],[-73.97317,40.76455],[-73.9495,40.7969]]]}),
    dynamic({"type":"Polygon","coordinates":[[[-73.94622,40.79249],[-73.96888,40.79282],[-73.9577,40.7789],[-73.94622,40.79249]]]}),
    dynamic({"type":"Polygon","coordinates":[[[-73.97335,40.77274],[-73.9936,40.76630],[-73.97171,40.75655],[-73.97335,40.77274]]]})
]
| summarize polygons_arr = make_list(polygons)
| project polygons_union = geo_union_polygons_array(polygons_arr)

输出

polygons_union
{"type":"Polygon","coordinates":[[[-73.972599326729608,40.765330371902991],[-73.960302383706178,40.782140794645024],[-73.9577,40.7789],[-73.94622,40.79249],[-73.9526593223173,40.792584227716468],[-73.9495,40.7969],[-73.95807,40.80068],[-73.9639277517478,40.792748258673875],[-73.96888,40.792819999999992],[-73.9662719791645,40.7895734224338],[-73.9803360309571,40.770518810606404],[-73.9936,40.7663],[-73.97171,40.756550000000004],[-73.972599326729608,40.765330371902991]]]}

下面的示例对多边形列执行地理空间合并。

datatable(polygon1:dynamic, polygon2:dynamic)
[
    dynamic({"type":"Polygon","coordinates":[[[-73.9495,40.7969],[-73.95807,40.80068],[-73.98201,40.76825],[-73.97317,40.76455],[-73.9495,40.7969]]]}), dynamic({"type":"Polygon","coordinates":[[[-73.94622,40.79249],[-73.96888,40.79282],[-73.9577,40.7789],[-73.94622,40.79249]]]})
]
| project polygons_arr = pack_array(polygon1, polygon2)
| project polygons_union = geo_union_polygons_array(polygons_arr)

输出

polygons_union
{"type":"Polygon","coordinates":[[[-73.9495,40.7969],[-73.95807,40.80068],[-73.9639277517478,40.792748258673875],[-73.96888,40.792819999999992],[-73.9662719791645,40.7895734224338],[-73.98201,40.76825],[-73.97317,40.76455],[-73.960302383706178,40.782140794645024],[-73.9577,40.7789],[-73.94622,40.79249],[-73.9526593223173,40.792584227716468],[-73.9495,40.7969]]]}

以下示例由于多边形之一无效而返回 True。

datatable(polygons:dynamic)
[
    dynamic({"type":"Polygon","coordinates":[[[-73.9495,40.7969],[-73.95807,40.80068],[-73.98201,40.76825],[-73.97317,40.76455],[-73.9495,40.7969]]]}),
    dynamic({"type":"Polygon","coordinates":[[[-73.94622,40.79249]]]})
]
| summarize polygons_arr = make_list(polygons)
| project invalid_union = isnull(geo_union_polygons_array(polygons_arr))

输出

invalid_union
True